Rename Foreign Key Constraints

DECLARE @SchemaName sysname = NULL;
DECLARE @TableName sysname = NULL;
DECLARE @ColumnName sysname = NULL;

WITH ConstraintColumns AS
  (
    SELECT  DISTINCT
            rc.CONSTRAINT_NAME,
            rc.CONSTRAINT_CATALOG,
            rc.CONSTRAINT_SCHEMA,
            rc.TABLE_NAME,
            CONSTRAINT_COLUMNS = STUFF(
                                   ( SELECT     ', ' + kcu.COLUMN_NAME
                                       FROM     INFORMATION_SCHEMA.KEY_COLUMN_USAGE AS kcu
                                       WHERE    kcu.CONSTRAINT_NAME = rc.CONSTRAINT_NAME
                                     FOR XML PATH( '' ), TYPE).value( '.', 'NVARCHAR(MAX)' ), 1, 2, '' )
      FROM  INFORMATION_SCHEMA.KEY_COLUMN_USAGE AS rc
  ),
     Statements AS
  (
    SELECT          SQLDrop = 'IF EXISTS (SELECT * FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS WHERE CONSTRAINT_NAME = ''' + Source.CONSTRAINT_NAME + ''' AND CONSTRAINT_SCHEMA = '''
                              + Source.CONSTRAINT_SCHEMA + ''' AND CONSTRAINT_CATALOG = DB_NAME()) BEGIN ALTER TABLE ' + Source.CONSTRAINT_SCHEMA + '.' + Source.TABLE_NAME + ' DROP CONSTRAINT '
                              + Source.CONSTRAINT_NAME + ' END',
                    SQLAdd = 'ALTER TABLE ' + Source.CONSTRAINT_SCHEMA + '.' + Source.TABLE_NAME + ' WITH NOCHECK ADD CONSTRAINT [FK_' + Source.TABLE_NAME + '_'
                             + REPLACE( Source.CONSTRAINT_COLUMNS, ', ', '' ) + '_' + Referenced.CONSTRAINT_SCHEMA + Referenced.TABLE_NAME + '] FOREIGN KEY(' + Source.CONSTRAINT_COLUMNS + ') REFERENCES ['
                             + Referenced.CONSTRAINT_SCHEMA + '].[' + Referenced.TABLE_NAME + '](' + Referenced.CONSTRAINT_COLUMNS + ');',
                    SQLEnable = 'ALTER TABLE ' + Source.CONSTRAINT_SCHEMA + '.' + Source.TABLE_NAME + ' WITH CHECK CHECK CONSTRAINT [FK_' + Source.TABLE_NAME + '_'
                                + REPLACE( Source.CONSTRAINT_COLUMNS, ', ', '' ) + '_' + Referenced.CONSTRAINT_SCHEMA + Referenced.TABLE_NAME + ']',
                    CurrentConstraintName = Source.CONSTRAINT_NAME,
                    ProposedConstraintName = 'FK_' + Source.TABLE_NAME + '_' + REPLACE( Source.CONSTRAINT_COLUMNS, ', ', '' ) + '_' + Referenced.CONSTRAINT_SCHEMA + Referenced.TABLE_NAME,
                    NumRank = ROW_NUMBER() OVER (ORDER BY Source.CONSTRAINT_SCHEMA, Source.TABLE_NAME)
      FROM          INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS AS RC
      INNER JOIN    ConstraintColumns AS Source
        ON Source.CONSTRAINT_CATALOG = RC.CONSTRAINT_CATALOG
           AND  Source.CONSTRAINT_SCHEMA = RC.CONSTRAINT_SCHEMA
           AND  Source.CONSTRAINT_NAME = RC.CONSTRAINT_NAME
      INNER JOIN    ConstraintColumns AS Referenced
        ON Referenced.CONSTRAINT_CATALOG = RC.UNIQUE_CONSTRAINT_CATALOG
           AND  Referenced.CONSTRAINT_SCHEMA = RC.UNIQUE_CONSTRAINT_SCHEMA
           AND  Referenced.CONSTRAINT_NAME = RC.UNIQUE_CONSTRAINT_NAME
      WHERE         ( Source.TABLE_NAME LIKE '%' + @TableName + '%'
                      OR      Referenced.TABLE_NAME LIKE '%' + @TableName + '%'
                      OR      @TableName IS NULL)
                    AND
                      ( Source.CONSTRAINT_COLUMNS LIKE '%' + @ColumnName + '%'
                        OR    Referenced.CONSTRAINT_COLUMNS LIKE '%' + @ColumnName + '%'
                        OR    @ColumnName IS NULL)
                    AND
                      ( Source.CONSTRAINT_SCHEMA = @SchemaName
                        OR    Referenced.CONSTRAINT_SCHEMA = @SchemaName
                        OR    @SchemaName IS NULL)
  )
  SELECT        Statements.SQLDrop,
                Statements.SQLAdd,
                Statements.SQLEnable,
                Statements.CurrentConstraintName,
                Statements.ProposedConstraintName,
                LenConstraintName = LEN( Statements.ProposedConstraintName )
    FROM        Statements
    WHERE       Statements.CurrentConstraintName <> Statements.ProposedConstraintName
    ORDER BY    Statements.NumRank;