Convert Interger to Binary String for Bit Masks

-------------------------------------------------------------------
-- Turn an Integer into a base two Binary String
-- By: Robert Rinchuse Jr
--
-- PRINT dbo.fn_GetBitString(123456,32)
-------------------------------------------------------------------
CREATE FUNCTION dbo.fn_GetBitString
(
  @IntValue Int
, @BitSize tinyInt --1 to 32
)
RETURNS varchar(32)
AS
BEGIN
DECLARE @BitNum tinyint, @BitString varchar(32)

IF @BitSize>32 SET @BitSize=32

SELECT @BitNum=1, @BitString=''

WHILE @BitNum<=@BitSize
Begin
SELECT @BitString=
Cast( (convert(bigint,(@IntValue/power(cast(2 as bigint),@BitNum-1))) % 2)  as char(1))
-- Cast( dbo.fn_GetBit(@IntValue ,@BitNum)  as char(1))
+@BitString
SELECT @BitNum=@BitNum+1
End 

RETURN @BitString

END
GO

-------------------------------------------------------------------
-- Get a specific Bit value from and Integer
-- Useful if you are saving a Bit Mask as an integer
-- By: Robert Rinchuse Jr
--
-- PRINT dbo.fn_GetBit(123456,7)
-------------------------------------------------------------------
CREATE FUNCTION dbo.fn_GetBit
(
  @IntValue Int
, @BitNum tinyInt --1 to 32
)
RETURNS bit
AS
BEGIN

RETURN Cast( (convert(bigint,(@IntValue/power(cast(2 as bigint),@BitNum-1))) % 2)  as bit)

END
GO

-------------------------------------------------------------------
-- Turn a base two Binary String into an integer
-- By: Robert Rinchuse Jr
--
-- PRINT dbo.fn_GetIntFromBitString('11111001001001110011')
-------------------------------------------------------------------
-- PRINT dbo.fn_GetBitString(1020531,32)
-- PRINT dbo.fn_GetIntFromBitString(dbo.fn_GetBitString(1020531,32))
-- PRINT dbo.fn_GetBitString(dbo.fn_GetIntFromBitString('11111001001001110011'),32)
-------------------------------------------------------------------
CREATE FUNCTION dbo.fn_GetIntFromBitString
(
  @BitString varchar(32)
)
RETURNS Int
AS
BEGIN

DECLARE @BitNum tinyint, @IntValue int, @BitSize tinyint
SELECT @BitNum=1, @IntValue=0, @BitSize=LEN(IsNull(@BitString,''))

SELECT @BitString = REVERSE( @BitString )

WHILE @BitNum<=@BitSize
Begin
SELECT @IntValue=@IntValue+
Cast(SUBSTRING(@BitString,@BitNum,1) as BigInt)*POWER(cast(2 as bigint),@BitNum-1)

SELECT @BitNum=@BitNum+1
End 

RETURN @IntValue

END

GO