DiskANN Experiment — Exploring Entry Points and Graph Neighborhoods

DECLARE @QueryVector VECTOR(768, FLOAT32);
-- Get the embedding of our example article.
SELECT @QueryVector = embedding
FROM dbo.ArticlesEmbeddings_FP32
WHERE hn_id = 18349232;
-- Find the 10 most similar articles.
SELECT TOP (10)
    e.hn_id,
    vs.distance
FROM VECTOR_SEARCH(
    TABLE = dbo.ArticlesEmbeddings_FP32 AS e,
    COLUMN = embedding,
    SIMILAR_TO = @QueryVector,
    METRIC = 'cosine',
    TOP_N = 11
) AS vs
WHERE e.hn_id <> 18349232
ORDER BY vs.distance;

SELECT
 i.name,
 vi.vector_index_type as index,
 vi.distance_metric,
 vi.build_parameters
FROM sys.vector_indexes AS vi
JOIN sys.indexes AS i
 ON i.object_id = vi.object_id
AND i.index_id  = vi.index_id;

USE [HackerNews]
GO
CREATE TABLE [dbo].[HackerNewsStories](
[hn_id] [int] NOT NULL,
[type_value] [nvarchar](50) NULL,
[by_user] [nvarchar](200) NULL,
[time_value] [bigint] NULL,
[title] [nvarchar](max) NULL,
 [nvarchar](max) NULL,
[score] [int] NULL,
[descendants] [int] NULL,
[actualtext] [nvarchar](max) NULL,
CONSTRAINT [PK_HackerNewsStories_hn_id] PRIMARY KEY CLUSTERED
(
[hn_id] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
CREATE TABLE [dbo].[ArticlesEmbeddings_FP16](
[embedding_id] [int] IDENTITY(1,1) NOT NULL,
[hn_id] [bigint] NOT NULL,
[n_tokens] [int] NOT NULL,
[embedding] [vector](768, float16) NULL,
[created_at] [datetime2](7) NOT NULL,
PRIMARY KEY CLUSTERED
(
[embedding_id] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
) ON [PRIMARY]
GO
CREATE TABLE [dbo].[ArticlesEmbeddings_FP32](
[embedding_id] [int] IDENTITY(1,1) NOT NULL,
[hn_id] [bigint] NOT NULL,
[n_tokens] [int] NOT NULL,
[embedding] [vector](768, float32) NULL,
[created_at] [datetime2](7) NOT NULL,
PRIMARY KEY CLUSTERED
(
[embedding_id] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
) ON [PRIMARY]
GO

USE [HackerNews]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE TABLE [dbo].[VectorSearchNode](
[GraphVectorID] [int] IDENTITY(1,1) NOT NULL,
[hn_id] [bigint] NOT NULL,
[FP32EmbeddingID] [int] NOT NULL,
[FP16EmbeddingID] [int] NOT NULL,
[Embedding32] [vector](768, float32) NOT NULL,
[Embedding16] [vector](768, float16) NOT NULL,
[IsQuery] [bit] NOT NULL,
[InFP32Result] [bit] NOT NULL,
[FP32Rank] [int] NULL,
[FP32ResultDistance] [float] NULL,
[InFP16Result] [bit] NOT NULL,
[FP16Rank] [int] NULL,
[FP16ResultDistance] [float] NULL,
CONSTRAINT [PK_VectorSearchNode] PRIMARY KEY CLUSTERED
(
[GraphVectorID] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY],
CONSTRAINT [UQ_VectorSearchNode_hn_id] UNIQUE NONCLUSTERED
(
[hn_id] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
)
AS NODE ON [PRIMARY]
GO
CREATE TABLE [dbo].[VectorSearchEdgeFP32](
[FromEmbeddingID] [int] NOT NULL,
[ToEmbeddingID] [int] NOT NULL,
[ToHnId] [bigint] NOT NULL,
[NeighborRank] [int] NOT NULL,
[SourceDistance] [float] NOT NULL,
CONSTRAINT [PK_VectorSearchEdgeFP32] PRIMARY KEY CLUSTERED
(
[FromEmbeddingID] ASC,
[ToEmbeddingID] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
) ON [PRIMARY]
GO
CREATE TABLE [dbo].[VectorSearchEdgeFP16](
[FromEmbeddingID] [int] NOT NULL,
[ToEmbeddingID] [int] NOT NULL,
[ToHnId] [bigint] NOT NULL,
[NeighborRank] [int] NOT NULL,
[SourceDistance] [float] NOT NULL,
CONSTRAINT [PK_VectorSearchEdgeFP16] PRIMARY KEY CLUSTERED
(
[FromEmbeddingID] ASC,
[ToEmbeddingID] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
) ON [PRIMARY]
GO

USE [HackerNews]
GO
ET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE   PROCEDURE [dbo].[BuildRobustNeighborsFP16_ExpA]
(
@FromEmbeddingID    int,
@CandidatePool      int = 192,
@R                  int = 48,
@Alpha              float = 1.2
)
AS
BEGIN
SET NOCOUNT ON;
SET XACT_ABORT ON;
IF @CandidatePool > 256
THROW 55101, 'CandidatePool must be <= 256.', 1;
IF @R > @CandidatePool
THROW 55102, 'R cannot exceed CandidatePool.', 1;
/*==============================================================
Check existing cached adjacency
==============================================================*/
DECLARE @ExistingBuiltAt datetime2(7);
SELECT
@ExistingBuiltAt = BuiltAt
FROM dbo.VectorAdjacencyBuildState_ExpA
WHERE Precision = 'FP16'
AND FromEmbeddingID = @FromEmbeddingID
AND CandidatePool = @CandidatePool
AND R = @R
AND Alpha = @Alpha;
/*
If this node has already been built using the same parameters,
reuse it unless a newer reciprocal-edge proposal exists.
*/
IF @ExistingBuiltAt IS NOT NULL
AND NOT EXISTS
(
SELECT 1
FROM dbo.VectorReverseProposalFP16_ExpA
WHERE OwnerEmbeddingID = @FromEmbeddingID
AND CreatedAt > @ExistingBuiltAt
)
BEGIN
RETURN;
END;
/*==============================================================
Rebuild this node's adjacency list
==============================================================*/
DELETE FROM dbo.VectorSearchEdgeFP16_ExpA
WHERE FromEmbeddingID = @FromEmbeddingID;
DELETE FROM dbo.VectorAdjacencyBuildState_ExpA
WHERE Precision = 'FP16'
AND FromEmbeddingID = @FromEmbeddingID;
/*==============================================================
Retrieve source vector
==============================================================*/
DECLARE @SourceVector vector(768,float16);
SELECT
@SourceVector = embedding
FROM dbo.ArticlesEmbeddings_FP16
WHERE embedding_id = @FromEmbeddingID;
IF @SourceVector IS NULL
THROW 55103, 'FP16 source embedding not found.', 1;
/*==============================================================
Candidate pool
Candidate generation uses VECTOR_SEARCH against the complete
FP16 table/index.
TOP_N = 257 gives us:
up to 256 candidate nodes
+ source vector itself
We retain @CandidatePool candidates after removing source.
==============================================================*/
CREATE TABLE #Pool
(
CandidateEmbeddingID int NOT NULL PRIMARY KEY,
CandidateHnId        bigint NOT NULL,
CandidateVector      vector(768,float16) NOT NULL,
DistanceFromSource   float NOT NULL,
IsActive             bit NOT NULL
);
INSERT #Pool
(
CandidateEmbeddingID,
CandidateHnId,
CandidateVector,
DistanceFromSource,
IsActive
)
SELECT TOP (@CandidatePool)
E.embedding_id,
E.hn_id,
E.embedding,
VS.distance,
1
FROM VECTOR_SEARCH
(
TABLE       = dbo.ArticlesEmbeddings_FP16 AS E,
COLUMN      = embedding,
SIMILAR_TO  = @SourceVector,
METRIC      = 'cosine',
TOP_N       = 257
) AS VS
WHERE E.embedding_id <> @FromEmbeddingID
ORDER BY
VS.distance,
E.embedding_id;
/*==============================================================
Add reciprocal-edge proposals
If another node previously selected:
OtherNode -> ThisNode
then we consider:
ThisNode -> OtherNode
as an additional candidate.
==============================================================*/
INSERT #Pool
(
CandidateEmbeddingID,
CandidateHnId,
CandidateVector,
DistanceFromSource,
IsActive
)
SELECT
E.embedding_id,
E.hn_id,
E.embedding,
VECTOR_DISTANCE
(
'cosine',
@SourceVector,
E.embedding
),
1
FROM dbo.VectorReverseProposalFP16_ExpA AS RP
INNER JOIN dbo.ArticlesEmbeddings_FP16 AS E
ON E.embedding_id = RP.CandidateEmbeddingID
LEFT JOIN #Pool AS P
ON P.CandidateEmbeddingID = E.embedding_id
WHERE RP.OwnerEmbeddingID = @FromEmbeddingID
AND E.embedding_id <> @FromEmbeddingID
AND P.CandidateEmbeddingID IS NULL;
/*==============================================================
Robust pruning
Repeatedly:
1. Select closest remaining candidate U.
2. Add U as a graph edge.
3. Remove U from candidate pool.
4. Remove candidates V that are sufficiently represented
by U.
Approximate pruning rule:
Alpha * distance(U,V)
<=
distance(Source,V)
Continue until:
R neighbors selected
OR
no candidates remain.
==============================================================*/
DECLARE @SelectedCount int = 0;
DECLARE @CurrentRank int = 0;
DECLARE @SelectedEmbeddingID int;
DECLARE @SelectedHnId bigint;
DECLARE @SelectedDistance float;
DECLARE @SelectedVector vector(768,float16);
WHILE @SelectedCount < @R
BEGIN
SET @SelectedEmbeddingID = NULL;
/*----------------------------------------------------------
Pick closest active candidate
----------------------------------------------------------*/
SELECT TOP (1)
@SelectedEmbeddingID =
P.CandidateEmbeddingID,
@SelectedHnId =
P.CandidateHnId,
@SelectedVector =
P.CandidateVector,
@SelectedDistance =
P.DistanceFromSource
FROM #Pool AS P
WHERE P.IsActive = 1
ORDER BY
P.DistanceFromSource,
P.CandidateEmbeddingID;
IF @SelectedEmbeddingID IS NULL
BREAK;
SET @SelectedCount += 1;
SET @CurrentRank += 1;
/*----------------------------------------------------------
Add selected neighbor to graph
----------------------------------------------------------*/
INSERT dbo.VectorSearchEdgeFP16_ExpA
(
FromEmbeddingID,
ToEmbeddingID,
ToHnId,
NeighborRank,
SourceDistance
)
VALUES
(
@FromEmbeddingID,
@SelectedEmbeddingID,
@SelectedHnId,
@CurrentRank,
@SelectedDistance
);
/*----------------------------------------------------------
Selected candidate is consumed
----------------------------------------------------------*/
UPDATE #Pool
SET IsActive = 0
WHERE CandidateEmbeddingID =
@SelectedEmbeddingID;
/*----------------------------------------------------------
Robust prune remaining candidates
U = selected neighbor
V = remaining candidate
Remove V when:
Alpha * distance(U,V)
<=
distance(Source,V)
This is what introduces diversity compared with simply
keeping the nearest 48 vectors.
----------------------------------------------------------*/
UPDATE P
SET IsActive = 0
FROM #Pool AS P
WHERE P.IsActive = 1
AND
(
@Alpha *
VECTOR_DISTANCE
(
'cosine',
@SelectedVector,
P.CandidateVector
)
)
<= P.DistanceFromSource;
END;
/*==============================================================
Generate reciprocal-edge proposals
Every selected:
Source -> Neighbor
proposes:
Neighbor -> Source
The proposal will be considered when Neighbor's adjacency
list is built/rebuilt.
==============================================================*/
INSERT dbo.VectorReverseProposalFP16_ExpA
(
OwnerEmbeddingID,
CandidateEmbeddingID
)
SELECT
E.ToEmbeddingID,
E.FromEmbeddingID
FROM dbo.VectorSearchEdgeFP16_ExpA AS E
LEFT JOIN dbo.VectorReverseProposalFP16_ExpA AS Existing
ON Existing.OwnerEmbeddingID =
E.ToEmbeddingID
AND Existing.CandidateEmbeddingID =
E.FromEmbeddingID
WHERE E.FromEmbeddingID =
@FromEmbeddingID
AND Existing.OwnerEmbeddingID IS NULL;
/*==============================================================
Mark adjacency list as built
==============================================================*/
INSERT dbo.VectorAdjacencyBuildState_ExpA
(
Precision,
FromEmbeddingID,
CandidatePool,
R,
Alpha,
BuiltAt
)
VALUES
(
'FP16',
@FromEmbeddingID,
@CandidatePool,
@R,
@Alpha,
SYSUTCDATETIME()
);
END;
GO

SELECT 'FP32' AS Precision,
    COUNT(DISTINCT FromEmbeddingID) AS BuiltSourceNodes,
    COUNT_BIG(*) AS TotalEdges,
    COUNT(DISTINCT ToEmbeddingID) AS DistinctDestinationNodes
FROM dbo.VectorSearchEdgeFP32_ExpA
UNION ALL
SELECT 'FP16', COUNT(DISTINCT FromEmbeddingID),
    COUNT_BIG(*), COUNT(DISTINCT ToEmbeddingID)
FROM dbo.VectorSearchEdgeFP16_ExpA;

WITH FP32Edges AS
(
 SELECT src.hn_id AS SourceHnId, g.ToHnId AS NeighborHnId
 FROM dbo.VectorSearchEdgeFP32_ExpA AS g
 JOIN dbo.ArticlesEmbeddings_FP32 AS src
   ON src.embedding_id = g.FromEmbeddingID
),
FP16Edges AS
(
 SELECT src.hn_id AS SourceHnId, g.ToHnId AS NeighborHnId
 FROM dbo.VectorSearchEdgeFP16_ExpA AS g
 JOIN dbo.ArticlesEmbeddings_FP16 AS src
   ON src.embedding_id = g.FromEmbeddingID
),
Combined AS
(
 SELECT COALESCE(a.SourceHnId,b.SourceHnId) AS SourceHnId,
        CASE WHEN a.NeighborHnId IS NULL THEN 0 ELSE 1 END AS InFP32,
        CASE WHEN b.NeighborHnId IS NULL THEN 0 ELSE 1 END AS InFP16
 FROM FP32Edges AS a
 FULL JOIN FP16Edges AS b
   ON a.SourceHnId=b.SourceHnId
  AND a.NeighborHnId=b.NeighborHnId
),
PerNode AS
(
 SELECT SourceHnId,
        SUM(InFP32) AS N32, SUM(InFP16) AS N16,
        SUM(CASE WHEN InFP32=1 AND InFP16=1 THEN 1 ELSE 0 END) AS Shared,
        COUNT(*) AS UnionCount
 FROM Combined GROUP BY SourceHnId
)
SELECT COUNT(*) AS ComparedNodes,
    CAST(AVG(1.0*N32) AS decimal(10,2)) AS AvgFP32Neighbors,
    CAST(AVG(1.0*N16) AS decimal(10,2)) AS AvgFP16Neighbors,
    CAST(AVG(1.0*Shared) AS decimal(10,2)) AS AvgSharedNeighbors,
    CAST(AVG(1.0*Shared/NULLIF(UnionCount,0)) AS decimal(10,4)) AS AvgJaccardSimilarity,
    CAST(MIN(1.0*Shared/NULLIF(UnionCount,0)) AS decimal(10,4)) AS MinJaccardSimilarity,
    CAST(MAX(1.0*Shared/NULLIF(UnionCount,0)) AS decimal(10,4)) AS MaxJaccardSimilarity
FROM PerNode;

WITH N32 AS
(
 SELECT src.hn_id AS SourceHnId, g.ToHnId AS NeighborHnId,
        g.NeighborRank AS Rank32
 FROM dbo.VectorSearchEdgeFP32_ExpA AS g
 JOIN dbo.ArticlesEmbeddings_FP32 AS src
   ON src.embedding_id=g.FromEmbeddingID
 WHERE src.hn_id IN (20594,11559412)
),
N16 AS
(
 SELECT src.hn_id AS SourceHnId, g.ToHnId AS NeighborHnId,
        g.NeighborRank AS Rank16
 FROM dbo.VectorSearchEdgeFP16_ExpA AS g
 JOIN dbo.ArticlesEmbeddings_FP16 AS src
   ON src.embedding_id=g.FromEmbeddingID
 WHERE src.hn_id IN (20594,11559412)
),
C AS
(
 SELECT COALESCE(a.SourceHnId,b.SourceHnId) AS SourceHnId,
        a.Rank32,b.Rank16
 FROM N32 AS a FULL JOIN N16 AS b
   ON a.SourceHnId=b.SourceHnId
  AND a.NeighborHnId=b.NeighborHnId
)
SELECT SourceHnId,
    COUNT(Rank32) AS FP32Neighbors,
    COUNT(Rank16) AS FP16Neighbors,
    SUM(CASE WHEN Rank32 IS NOT NULL AND Rank16 IS NOT NULL THEN 1 ELSE 0 END) AS SharedNeighbors,
    SUM(CASE WHEN Rank32=Rank16 THEN 1 ELSE 0 END) AS SameRankCount,
    CAST(AVG(CASE WHEN Rank32 IS NOT NULL AND Rank16 IS NOT NULL
                  THEN 1.0*ABS(Rank32-Rank16) END) AS decimal(10,2)) AS AvgAbsoluteRankDifference,
    MAX(CASE WHEN Rank32 IS NOT NULL AND Rank16 IS NOT NULL
             THEN ABS(Rank32-Rank16) END) AS MaxAbsoluteRankDifference
FROM C GROUP BY SourceHnId ORDER BY SourceHnId;

WITH N32 AS
(
 SELECT src.hn_id AS SourceHnId, g.ToHnId AS NeighborHnId,
        g.SourceDistance AS D32
 FROM dbo.VectorSearchEdgeFP32_ExpA AS g
 JOIN dbo.ArticlesEmbeddings_FP32 AS src
   ON src.embedding_id=g.FromEmbeddingID
 WHERE src.hn_id IN (20594,11559412)
),
N16 AS
(
 SELECT src.hn_id AS SourceHnId, g.ToHnId AS NeighborHnId,
        g.SourceDistance AS D16
 FROM dbo.VectorSearchEdgeFP16_ExpA AS g
 JOIN dbo.ArticlesEmbeddings_FP16 AS src
   ON src.embedding_id=g.FromEmbeddingID
 WHERE src.hn_id IN (20594,11559412)
)
SELECT a.SourceHnId, COUNT(*) AS SharedNeighbors,
    CAST(AVG(ABS(a.D32-b.D16)) AS decimal(18,10)) AS AvgAbsoluteDistanceDifference,
    CAST(MAX(ABS(a.D32-b.D16)) AS decimal(18,10)) AS MaxAbsoluteDistanceDifference,
    CAST(AVG(CASE WHEN a.D32<>0
                  THEN 100.0*ABS(a.D32-b.D16)/ABS(a.D32) END)
         AS decimal(18,6)) AS AvgRelativeDifferencePct
FROM N32 AS a JOIN N16 AS b
ON a.SourceHnId=b.SourceHnId AND a.NeighborHnId=b.NeighborHnId
GROUP BY a.SourceHnId ORDER BY a.SourceHnId;

DECLARE @Query32 vector(768,float32), @Query16 vector(768,float16);
SELECT @Query32=embedding FROM dbo.ArticlesEmbeddings_FP32 WHERE hn_id=18349232;
SELECT @Query16=embedding FROM dbo.ArticlesEmbeddings_FP16 WHERE hn_id=18349232;
WITH SharedNeighbors AS
(
   SELECT s.hn_id AS SourceHnId,g32.ToHnId AS CandidateHnId
   FROM dbo.VectorGraphSample AS s
   JOIN dbo.ArticlesEmbeddings_FP32 AS e32 ON e32.hn_id=s.hn_id
   JOIN dbo.ArticlesEmbeddings_FP16 AS e16 ON e16.hn_id=s.hn_id
   JOIN dbo.VectorSearchEdgeFP32_ExpA AS g32 ON g32.FromEmbeddingID=e32.embedding_id
   JOIN dbo.VectorSearchEdgeFP16_ExpA AS g16
     ON g16.FromEmbeddingID=e16.embedding_id AND g16.ToHnId=g32.ToHnId
),
Distances AS
(
   SELECT n.SourceHnId,n.CandidateHnId,
          VECTOR_DISTANCE('cosine',@Query32,e32.embedding) AS D32,
          VECTOR_DISTANCE('cosine',@Query16,e16.embedding) AS D16
   FROM SharedNeighbors AS n
   JOIN dbo.ArticlesEmbeddings_FP32 AS e32 ON e32.hn_id=n.CandidateHnId
   JOIN dbo.ArticlesEmbeddings_FP16 AS e16 ON e16.hn_id=n.CandidateHnId
),
Ranked AS
(
   SELECT *,
          ROW_NUMBER() OVER (PARTITION BY SourceHnId ORDER BY D32,CandidateHnId) AS Rank32,
          ROW_NUMBER() OVER (PARTITION BY SourceHnId ORDER BY D16,CandidateHnId) AS Rank16
   FROM Distances
),
PerNode AS
(
   SELECT SourceHnId,COUNT(*) AS SharedCandidates,
          SUM(CASE WHEN Rank32=Rank16 THEN 1 ELSE 0 END) AS SameRankCount,
          MAX(ABS(Rank32-Rank16)) AS MaxRankDifference
   FROM Ranked GROUP BY SourceHnId
)
SELECT COUNT(*) AS ComparedSourceNodes,
      SUM(SharedCandidates) AS TotalSharedCandidates,
      SUM(SameRankCount) AS TotalSameRankCandidates,
      CAST(100.0*SUM(SameRankCount)/NULLIF(SUM(SharedCandidates),0)
           AS decimal(10,4)) AS SameRankPercentage,
      SUM(CASE WHEN SameRankCount=SharedCandidates THEN 1 ELSE 0 END) AS NodesWithIdenticalRanking,
      SUM(CASE WHEN SameRankCount<SharedCandidates THEN 1 ELSE 0 END) AS NodesWithRankingDifferences,
      MAX(MaxRankDifference) AS LargestRankDisplacement
FROM PerNode;