use tempdb;
go
if object_id('dbo.TestTable') is not null drop table dbo.TestTable;
go
select top(1000000) t.rnd_txt as s
into dbo.TestTable
from
	(select char(convert(int,rand(checksum(newid()))*26+97))) c (rnd_char)
	cross apply (select convert(int,rand(checksum(newid()))*15+2)) l(rnd_len)
	cross apply (select replicate(c.rnd_char,l.rnd_len)+' ') w(rnd_word)
	cross apply (select convert(int,rand(checksum(newid()))*10+1)) wc(rnd_wcount)
	cross apply (select replicate(w.rnd_word,wc.rnd_wcount)+' ') t(rnd_txt)
	cross join sys.all_columns o1
	cross join sys.all_columns o2
;

create FUNCTION dbo.InitialCapFaster(@String VARCHAR(8000))
RETURNS table
AS
return
with 
c as
(
select 
	String   = STUFF(LOWER(@String),1,1,UPPER(LEFT(@String,1))) COLLATE Latin1_General_Bin,
    Position = PATINDEX('%[^A-Za-z''][a-z]%',@String COLLATE Latin1_General_Bin),
    Step = 1
union all
select 
	String   = STUFF(c.String,c.Position,2,UPPER(SUBSTRING(c.String,c.Position,2))) COLLATE Latin1_General_Bin,
    Position = PATINDEX('%[^A-Za-z''][a-z]%',c.String COLLATE Latin1_General_Bin),
    Step = c.Step+1
from c
where c.Position > 0
)
select top(1) String from c order by Step desc
go

declare @s varchar(8000);
declare @ds datetime = getdate();
select @s = dbo.InitialCap(s) from testtable;
print 'InitialCap: ' + convert(varchar(10),datediff(ms,@ds,getdate())) + ' ms'
go
declare @s varchar(8000);
declare @ds datetime = getdate();
select @s = f.String from dbo.testtable cross apply dbo.InitialCapFaster(s) f;
print 'InitialCapFaster: ' + convert(varchar(10),datediff(ms,@ds,getdate())) + ' ms'
go
print @@version

InitialCap: 25533 ms
InitialCapFaster: 12856 ms

Microsoft SQL Server 2008 R2 (RTM) - 10.50.1600.1 (Intel X86) 
	Apr  2 2010 15:53:02 
	Copyright (c) Microsoft Corporation
	Enterprise Edition on Windows NT 5.1 <X86> (Build 2600: Service Pack 3)