--=====================================
--	08-3	Make SEND into a Trigger
--=====================================
USE [SB_eDrugs]
Print ''
GO
CREATE TRIGGER [dbo].[trgWebUser_SendTo_PayPusher] ON [dbo].[WebUsers]
 FOR INSERT AS
BEGIN
/*
	Asynchronusly Send New Users info to PayPusher database.

test:
INSERT INTO WebUsers(LogonName,FirstName,LastName,ZipCode,Password)
 Select 'User01','Rob','Roberts', 90120,'MyNewPwd'
*/
	SET NOCOUNT ON

	-- get the number of records inserted.
	Declare @recs Int		
	Select @recs = (Select count(*) from inserted)
	IF @recs > 1 
	 BEGIN
		RAISERROR('[trgWebUser_SendTo_PayPusher]: cannot handle bulk Inserts!', 17, 1)
		ROLLBACK
		RETURN
	 END

	--====== SEND the message
	-- Get the new User's ID
	Declare @UserID as int
	Select @UserID = UserID From inserted

	-- Start the conversation
	Declare @ConvsHdl uniqueidentifier
	BEGIN DIALOG  @ConvsHdl
	   FROM SERVICE InitiatorReplyService
	   TO SERVICE 'PayPusherService'
	   ON CONTRACT conWebUser

	-- Send it & End it
	;SEND ON CONVERSATION @ConvsHdl
		Message Type msgNewUser
		( @UserId )
	END CONVERSATION @ConvsHdl
	--======
END
GO