ALTER TRIGGER [dbo].[tuReferral_UpdateAudit]
	ON [dbo].[tReferral]
FOR UPDATE
AS
-- Select the context information
DECLARE @sess VARBINARY(128), @var NVARCHAR(64)
SET @sess = (SELECT context_info FROM master.dbo.sysprocesses
 WHERE spid = @@spid)
SET @var  = ISNULL(CAST(@sess AS NVARCHAR(64)),'')
-- Keep Audit "Update" audit columns current (reflect data changes) for table: tReferral
UPDATE	tbl
SET
		tbl.UpdateLogin	= SUSER_SNAME()
		,tbl.UpdateApp		= SUBSTRING(APP_NAME(),1,64)
		,tbl.UpdateDateTime	= CURRENT_TIMESTAMP
FROM		dbo.tReferral tbl 
		JOIN (SELECT *,CHECKSUM(*) AS CSUM FROM inserted) i
			ON tbl.ReferralID = i.ReferralID
		JOIN (SELECT *,CHECKSUM(*) AS CSUM FROM deleted) d
			ON i.ReferralID = d.ReferralID
WHERE	i.CSUM != d.CSUM
		AND SUSER_SNAME() NOT IN ('sa','PKX\prodsqlsvc')
		and @var <> 'SKIPME'

Create Procedure MyProc
AS
BEGIN
DECLARE @var VARBINARY(128)
SET @var = CAST(N'SKIPME' AS VARBINARY(128))
SET CONTEXT_INFO @var

--do stuff

--disable the work around
SET @var = CAST(N'' AS VARBINARY(128))
SET CONTEXT_INFO @var
END --PROC

USE Utility_Db
GO
CREATE FUNCTION [dbo].[SetContextInfo] (
	@start int,
	@value varbinary(128)
	)
RETURNS varbinary(128)
AS
--SELECT dbo.SetContextInfo ( 10, 0xA1B2C3D4 ) --sample call that sets 4 bytes, starting at
--byte 10, other bytes are left unchanged; can set anywhere from 1 to 128 bytes
BEGIN
RETURN (
	SELECT 
		COALESCE(SUBSTRING(CONTEXT_INFO(), 1, @start - 1), CAST(REPLICATE(0x00, @start - 1) AS varbinary(128))) +
		@value +
		COALESCE(SUBSTRING(CONTEXT_INFO(), @start + DATALENGTH(@value), 128 - @start - DATALENGTH(@value) + 1), 0x)
	)
END --FUNCTION
GO


--Then in the set up code:

USE data_db
DECLARE @context_info varbinary(128)
SET @context_info = Utility_Db.dbo.SetContextInfo ( 10, 0xEE ) --starting byte, new value
SET CONTEXT_INFO @context_info
GO


--Finally, in the query that checks CONTEXT_INFO,
--  you can use a variable, as shown in the other code posted above;
--  or, if you prefer, you can just test CONTEXT_INFO directly:
...
and ISNULL(SUBSTRING(CONTEXT_INFO(), 10, 1), 0x00) <> 0xEE