set nocount on
set statistics io off
--Setting up the mock universe
if object_id('tempdb.dbo.#Stocks') is not null drop table #Stocks
create table #Stocks
(
    FundID varchar(10),
    TradingDate int, --we use MSDates
    SharesOutstanding int,
    SharesOutstandingChangeDate int
    
    primary key clustered (FundID, TradingDate)
)

declare 
    @loop int, 
    @Price float
    
select @loop = 39000

while @Loop <= 40000
begin

    insert into #Stocks (FundID, TradingDate)
    select 'AAA', @loop union all
    select 'BBB', @loop

    select @Loop = @Loop + 1

end

update #Stocks
set 
    SharesOutstanding = case FundID when 'AAA' then case TradingDate when 39002 then 40000
                                                                     when 39761 then 80000
                                                                     when 39987 then 70000
                                                    end
                                    when 'BBB' then case TradingDate when 39127 then 125
                                                                     when 39493 then 305
                                                    end
                        end,
    SharesOutstandingChangeDate = case FundID when 'AAA' then case when TradingDate in (39002, 39761, 39987) then TradingDate 
                                                                   else null
                                                              end
                                              when 'BBB' then case when TradingDate in (39127, 39493) then TradingDate
                                                                   else null
                                                              end
                                  end
                                  
--this is the statement I'm really looking to improve upon.
set statistics io on
;with Propagate as (select
                        TradingDate = b.TradingDate,
                        SharesOutstanding = a.SharesOutstanding,
                        AsOfDate = b.AsOfDate
                    from #Stocks a
                    inner join (select
                                    TradingDate = s2.TradingDate,
                                    AsOfDate = max(s1.SharesOutstandingChangeDate)
                                from #Stocks s1
                                inner join #Stocks s2
                                    on s1.SharesOutstandingChangeDate <= s2.TradingDate
                                group by s2.TradingDate) b
                        on a.TradingDate = b.AsOfDate)
update s
set SharesOutstanding = p.SharesOutstanding
from #Stocks s
inner join Propagate p
    on s.TradingDate = p.TradingDate

;with Propagate as (
select
	TradingDate = b.TradingDate,
	SharesOutstanding = a.SharesOutstanding,
	AsOfDate = b.AsOfDate,
	FundID = a.FundID
from #Stocks a
	inner join (
		select
			FundID = s2.FundID,
			TradingDate = s2.TradingDate,
			AsOfDate = max(s1.SharesOutstandingChangeDate)
		from #Stocks s1
			inner join #Stocks s2 on s1.SharesOutstandingChangeDate <= s2.TradingDate 
				and s1.FundID = s2.FundID
		group by s2.FundID, s2.TradingDate
		) b on a.TradingDate = b.AsOfDate 
			and a.FundID = b.FundID
)
--update s
--set SharesOutstanding = p.SharesOutstanding
select *
from #Stocks s
inner join Propagate p
    on s.TradingDate = p.TradingDate 
	and s.FundID = p.FundID