--SQL
SELECT DATEADD(dd,14,getdate()); --2011-08-10 11:18:44.630
--ORACLE
SELECT DATEADD('dd',14,SYSDATE) FROM DUAL; --10-AUG-11 11.18.03.000000000 AM

CREATE OR REPLACE PACKAGE "YOURUSER"."SQLSERVER_UTILITIES" AS
FUNCTION DATEADD(DATEINTERVAL       VARCHAR2, VALUE NUMBER, DT TIMESTAMP) RETURN TIMESTAMP;
FUNCTION DATEDIFF(DATEINTERVAL      VARCHAR2, START_DATETIME DATE, END_DATETIME DATE) RETURN NUMBER;
FUNCTION DATENAME(DATEINTERVAL      VARCHAR2, DT TIMESTAMP) RETURN VARCHAR2;
FUNCTION DATEPART(DATEINTERVAL      VARCHAR2, DT TIMESTAMP) RETURN NUMBER;
FUNCTION DAY(DT TIMESTAMP) RETURN   NUMBER;
FUNCTION MONTH(DT TIMESTAMP) RETURN NUMBER;
FUNCTION YEAR(DT TIMESTAMP) RETURN  NUMBER;
FUNCTION SUBSTRING(CHAR_EXPRESION   VARCHAR2, START_POSITION NUMBER, SUBSTRING_LENGTH NUMBER) RETURN VARCHAR2;
FUNCTION LEFT(CHAR_EXPRESION        VARCHAR2, SUBSTRING_LENGTH NUMBER) RETURN VARCHAR2;
FUNCTION RIGHT(CHAR_EXPRESION       VARCHAR2, SUBSTRING_LENGTH NUMBER) RETURN VARCHAR2;
END SQLSERVER_UTILITIES; /
 

  CREATE OR REPLACE PACKAGE BODY "YOURUSERNAME"."SQLSERVER_UTILITIES" AS
FUNCTION DATEADD(DATEINTERVAL VARCHAR2, VALUE NUMBER, DT TIMESTAMP)
RETURN TIMESTAMP
IS
  RET_VALUE TIMESTAMP;
  PART VARCHAR2(15);
  PART_VALUE NUMBER;
BEGIN
  PART := UPPER(DATEINTERVAL);
  PART_VALUE := TRUNC(VALUE);
  IF PART IN ('YEAR', 'YY', 'YYYY') THEN
    RET_VALUE := DT + NUMTOYMINTERVAL(PART_VALUE, 'YEAR');
  ELSIF PART IN ('QUARTER', 'QQ', 'Q') THEN
    RET_VALUE := DT + NUMTOYMINTERVAL(PART_VALUE * 3, 'MONTH');
  ELSIF PART IN ('MONTH', 'MM', 'M') THEN
    RET_VALUE := DT + NUMTOYMINTERVAL(PART_VALUE, 'MONTH');
  ELSIF PART IN ('DAYOFYEAR', 'DY', 'Y', 'DAY', 'DD', 'D', 'WEEKDAY', 'DW', 'W') THEN
    RET_VALUE := DT + NUMTODSINTERVAL(PART_VALUE, 'DAY');
  ELSIF PART IN ('WEEK', 'WK', 'WW') THEN
    RET_VALUE := DT + NUMTODSINTERVAL(PART_VALUE * 7, 'DAY');
  ELSIF PART IN ('HOUR', 'HH') THEN
    RET_VALUE := DT + NUMTODSINTERVAL(PART_VALUE, 'HOUR');
  ELSIF PART IN ('MINUTE', 'MI', 'N') THEN
    RET_VALUE := DT + NUMTODSINTERVAL(PART_VALUE, 'MINUTE');
  ELSIF PART IN ('SECOND', 'SS', 'S') THEN
    RET_VALUE := DT + NUMTODSINTERVAL(PART_VALUE, 'SECOND');
  ELSIF PART IN ('MILLISECOND', 'MS') THEN
    RET_VALUE := DT + NUMTODSINTERVAL(PART_VALUE / 1000, 'SECOND');
  END IF;
  RETURN RET_VALUE;
 EXCEPTION
   WHEN OTHERS THEN
      RETURN NULL;
 END DATEADD;

FUNCTION DATEDIFF(DATEINTERVAL VARCHAR2, START_DATETIME DATE, END_DATETIME DATE)
RETURN NUMBER
IS
  RET_VALUE NUMBER;
  PART VARCHAR2(15);
BEGIN
    PART := UPPER(DATEINTERVAL);
   IF PART IN ('YEAR', 'YY', 'YYYY','Y') THEN
       RET_VALUE := TO_NUMBER(TO_CHAR(END_DATETIME, 'YYYY')) - TO_NUMBER(TO_CHAR(START_DATETIME, 'YYYY'));
    ELSIF PART IN ('QUARTER', 'QQ', 'Q') THEN
      RET_VALUE := MONTHS_BETWEEN( END_DATETIME, START_DATETIME) /3;
    ELSIF PART IN ('MONTH', 'MM', 'M') THEN
       RET_VALUE := MONTHS_BETWEEN( END_DATETIME, START_DATETIME);
    ELSIF PART IN ('DAY', 'DD', 'D') THEN
       RET_VALUE := END_DATETIME - START_DATETIME;
    END IF;
    RETURN TRUNC(RET_VALUE);
 EXCEPTION
   WHEN OTHERS THEN
      RETURN NULL;
 END DATEDIFF;

FUNCTION DATENAME(DATEINTERVAL VARCHAR2, DT TIMESTAMP)
RETURN VARCHAR2
IS
  RET_VALUE VARCHAR2(20);
  PART VARCHAR2(15);
BEGIN
    PART := UPPER(DATEINTERVAL);

    IF    PART IN ('YEAR', 'YY', 'YYYY') THEN RET_VALUE := TO_CHAR(DT, 'YYYY');
    ELSIF PART IN ('QUARTER', 'QQ', 'Q') THEN RET_VALUE := TO_CHAR(DT, 'Q');
    ELSIF PART IN ('MONTH', 'MM', 'M'  ) THEN RET_VALUE := TO_CHAR(DT, 'MONTH');
    ELSIF PART IN ('DAYOFYEAR', 'DY', 'Y') THEN RET_VALUE := TO_CHAR(DT, 'DDD');
    ELSIF PART IN ('DAY', 'DD', 'D'    ) THEN RET_VALUE := TO_CHAR(DT, 'DD');
    ELSIF PART IN ('WEEKDAY', 'DW', 'W') THEN RET_VALUE := TO_CHAR(DT, 'DAY');
    ELSIF PART IN ('WEEK', 'WK', 'WW'  ) THEN RET_VALUE := TO_CHAR(DT, 'IW');
    ELSIF PART IN ('HOUR', 'HH'        ) THEN RET_VALUE := TO_CHAR(DT, 'HH24');
    ELSIF PART IN ('MINUTE', 'MI', 'N' ) THEN RET_VALUE := TO_CHAR(DT, 'MI');
    ELSIF PART IN ('SECOND', 'SS', 'S' ) THEN RET_VALUE := TO_CHAR(DT, 'SS');
    ELSIF PART IN ('MILLISECOND', 'MS' ) THEN RET_VALUE := TO_CHAR(DT, 'FF3');
    END IF;
    RETURN RET_VALUE;
EXCEPTION
  WHEN OTHERS THEN
    RETURN NULL;
END DATENAME;

FUNCTION DATEPART(DATEINTERVAL VARCHAR2, DT TIMESTAMP)
RETURN NUMBER
IS
  RET_VALUE NUMBER;
  PART VARCHAR2(15);
BEGIN
    PART := UPPER(DATEINTERVAL);
    IF    PART IN ('YEAR', 'YY', 'YYYY'  )   THEN RET_VALUE := TO_CHAR(DT, 'YYYY');
    ELSIF PART IN ('QUARTER', 'QQ', 'Q'  )   THEN RET_VALUE := TO_CHAR(DT, 'Q'   );
    ELSIF PART IN ('MONTH', 'MM', 'M'    )   THEN RET_VALUE := TO_CHAR(DT, 'MM'  );
    ELSIF PART IN ('DAYOFYEAR', 'DY', 'Y')   THEN RET_VALUE := TO_CHAR(DT, 'DDD' );
    ELSIF PART IN ('DAY', 'DD', 'D'      )   THEN RET_VALUE := TO_CHAR(DT, 'DD'  );
    ELSIF PART IN ('WEEKDAY', 'DW', 'W'  )   THEN RET_VALUE := TO_CHAR(DT, 'D'   );
    ELSIF PART IN ('WEEK', 'WK', 'WW'    )   THEN RET_VALUE := TO_CHAR(DT, 'IW'  );
    ELSIF PART IN ('HOUR', 'HH       '   )   THEN RET_VALUE := TO_CHAR(DT, 'HH24');
    ELSIF PART IN ('MINUTE', 'MI', 'N'   )   THEN RET_VALUE := TO_CHAR(DT, 'MI'  );
    ELSIF PART IN ('SECOND', 'SS', 'S'   )   THEN RET_VALUE := TO_CHAR(DT, 'SS'  );
    ELSIF PART IN ('MILLISECOND', 'MS'   )   THEN RET_VALUE := TO_CHAR(DT, 'FF3' );
    END IF;
    RETURN RET_VALUE;
EXCEPTION
  WHEN OTHERS THEN
    RETURN NULL;
END DATEPART;

FUNCTION DAY(DT TIMESTAMP)
RETURN NUMBER
IS
BEGIN
    RETURN DATEPART('DAY', DT);
END DAY;

FUNCTION MONTH(DT TIMESTAMP)
RETURN NUMBER
IS
BEGIN
    RETURN DATEPART('MONTH', DT);
END MONTH;

FUNCTION YEAR(DT TIMESTAMP)
RETURN NUMBER
IS
BEGIN
    RETURN DATEPART('YEAR', DT);
END YEAR;

FUNCTION SUBSTRING(CHAR_EXPRESION VARCHAR2, START_POSITION NUMBER, SUBSTRING_LENGTH NUMBER)
RETURN VARCHAR2
IS
BEGIN
    RETURN SUBSTR(CHAR_EXPRESION, START_POSITION, SUBSTRING_LENGTH);
END SUBSTRING;

FUNCTION LEFT(CHAR_EXPRESION VARCHAR2, SUBSTRING_LENGTH NUMBER)
RETURN VARCHAR2
IS
BEGIN
    RETURN SUBSTR(CHAR_EXPRESION, 0, SUBSTRING_LENGTH);
END LEFT;

FUNCTION RIGHT(CHAR_EXPRESION VARCHAR2, SUBSTRING_LENGTH NUMBER)
RETURN VARCHAR2
IS
BEGIN
    RETURN SUBSTR(CHAR_EXPRESION, -SUBSTRING_LENGTH, SUBSTRING_LENGTH);
END RIGHT;

END SQLSERVER_UTILITIES; /