DECLARE @dtFrom DATETIME;
DECLARE @dtTo DATETIME;
DECLARE @dtStart DATETIME;

SELECT
    @dtFrom = '2010-01-01T00:00:00.000',
    @dtTo = '2010-12-31T00:00:00.000';

SET @dtStart = GETDATE();

CREATE TABLE #Dates
(
	[Date] DATETIME NOT NULL PRIMARY KEY,
	[SomeValueForDate] INT NOT NULL
);

WITH
	n2 (n) AS (SELECT 1 UNION ALL SELECT 0), -- 2 entries
	n4 (n) AS (SELECT 1 FROM n2 x CROSS JOIN n2 y), -- 4 entries
	n16 (n) AS (SELECT 1 FROM n4 x CROSS JOIN n4 y), -- 16 entries
	n256 (n) AS (SELECT 1 FROM n16 x CROSS JOIN n16 y), -- 256 entries
	n65536 (n) AS (SELECT 1 FROM n256 x CROSS JOIN n256 y), -- 65536 entries
	nmax (n) AS (SELECT 1 FROM n65536 x CROSS JOIN n256 y), -- 16777216 entries (would never be reached as max date = 9999-12-31T00:00:00 = 2958463)
	num (n) AS (SELECT ROW_NUMBER() OVER (ORDER BY n) FROM nmax)
INSERT INTO
	[#Dates]
SELECT
	DATEADD(DAY, n-1, @dtFrom),
	n
FROM
	num
WHERE
	n <=  DATEDIFF(DAY, @dtFrom, @dtTo) + 1;

SELECT DATEDIFF(MS, @dtStart, GETDATE()) AS [Runtime in msec];
SELECT * FROM [#Dates] ORDER BY 1;
DROP TABLE #Dates;