Yup, looks good.

For future reference, here is an example:

'APP_DataBase (vba)

'

' This is the module for the APP application's

'Database functions, routines and constants.

'

'2007-06-08 B.Young Created

'

Option Explicit

Public appDB As New ADODB.Connection

Public Function IsOpenDB() As Boolean

' function to track the DB status

IsOpenDB = (appDB.State <> 0) ' 0=closed

End Function

Public Sub CloseDB()

'Close the database if it is open.

If IsOpenDB Then appDB.Close

End Sub

Public Function OpenDB() As Boolean

'Open the Database and indicate if sucessful

Static sPrev As String

Dim sFile As String

If IsOpenDB Then

OpenDB = True 'we are already open

Exit Function

End If

If sPrev = "" Then sPrev = GetSetting(APP_AppName, "History", "DBName")

With Application.FileDialog(msoFileDialogFilePicker)

'specify the file open dialog

.AllowMultiSelect = False

.Filters.Clear

.Filters.Add "Access Workbooks", "*.mdb"

.Filters.Add "All Files", "*.*"

.InitialFileName = sPrev

.Title = "Open TIP Database"

.Show

If .SelectedItems.Count > 0 Then

sFile = .SelectedItems(1)

Else 'user canceled ...

OpenDB = False

Exit Function

End If

End With

'appDB.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\byoung\APP\Main.mdb"

appDB.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & sFile

On Error Resume Next

appDB.Open

If Err.Number <> 0 Then

MsgBox "Error(" & Err.Number & "): " & Err.Description, vbOKOnly + vbCritical, "Error in OpenDB"

OpenDB = False

Exit Function

End If

'Opened ok, so finsh-up and exit

OpenDB = True

sPrev = sFile

SaveSetting APP_AppName, "History", "DBName", sPrev

End Function

Public Function DBLookup(SQLCommand As String, Optional DefaultVal As Variant = "") As Variant

'Execute a SQL statement and return a single value.

Dim rs As Recordset

On Error GoTo ErrHandler 'Handle any/all DB errors

If Not IsOpenDB Then OpenDB

' execute the command

Set rs = appDB.Execute(SQLCommand)

' extract the first field of the first record returned

rs.MoveFirst

DBLookup = rs.Fields(0).Value

Exit Function

ErrHandler:

' whatever the error is, just assign the default value and return

DBLookup = DefaultVal

Exit Function

End Function

Public Sub DBExecute(SQLCommand As String, Optional RecordsAffected As Long = 0)

'Execute a SQL statement that returns no values.

If Not IsOpenDB Then OpenDB

appDB.Execute SQLCommand, RecordsAffected

End Sub

'===================

Thanks!