Click here to monitor SSC
SQLServerCentral is supported by Red Gate Software Ltd.
 
Log in  ::  Register  ::  Not logged in
 
 
 

Conditional reIndex and update stats.

Hi,
 
This script is very helpful, specially for sql server 2000. I made some changes into this.
 
Thanx to T.Pullen for this script.
---------------------------->SP BEGIN
CREATE PROCEDURE sp_defragment_indexes @maxfrag DECIMAL
AS
/* T.Pullen
This stored procedure checks index fragmentation in a database and defragments
indexes whose scan densities fall below a specified threshold, @magfrag, which
is passed to the SP. This SP was initially based on a code sample in SQL Server 2000
Books Online.
Must be run in the database to be defragmented.
*/

-- Declare variables
SET NOCOUNT ON
DECLARE @tablename VARCHAR (128)
DECLARE @execstr VARCHAR (255)
DECLARE @objectid INT
DECLARE @objectowner VARCHAR(255)
DECLARE @indexid INT
DECLARE @frag DECIMAL
DECLARE @indexname CHAR(255)
DECLARE @dbname sysname
DECLARE @tableid INT
DECLARE @tableidchar VARCHAR(255)
--check this is being run in a user database
SELECT @dbname = db_name()
IF @dbname IN ('master', 'msdb', 'model', 'tempdb')
BEGIN
PRINT 'This procedure should not be run in system databases.'
RETURN
END
--begin Stage 1: checking fragmentation
-- Declare cursor
DECLARE tables CURSOR FOR
SELECT convert(varchar,so.id)
FROM sysobjects so
JOIN sysindexes si
ON so.id = si.id
WHERE so.type ='U'
AND si.indid < 2
AND si.rows > 0
-- Create the temporary table to hold fragmentation information
CREATE TABLE #fraglist (
ObjectName CHAR (255),
ObjectId INT,
IndexName CHAR (255),
IndexId INT,
Lvl INT,
CountPages INT,
CountRows INT,
MinRecSize INT,
MaxRecSize INT,
AvgRecSize INT,
ForRecCount INT,
Extents INT,
ExtentSwitches INT,
AvgFreeBytes INT,
AvgPageDensity INT,
ScanDensity DECIMAL,
BestCount INT,
ActualCount INT,
LogicalFrag DECIMAL,
ExtentFrag DECIMAL)
-- Open the cursor
OPEN tables
-- Loop through all the tables in the database running dbcc showcontig on each one
FETCH NEXT
FROM tables
INTO @tableidchar
WHILE @@FETCH_STATUS = 0
BEGIN
-- Do the showcontig of all indexes of the table
INSERT INTO #fraglist
EXEC ('DBCC SHOWCONTIG (' + @tableidchar + ') WITH FAST, TABLERESULTS, ALL_INDEXES, NO_INFOMSGS')
FETCH NEXT
FROM tables
INTO @tableidchar
END
-- Close and deallocate the cursor
CLOSE tables
DEALLOCATE tables
-- Report the ouput of showcontig for results checking
SELECT * FROM #fraglist
-- Begin Stage 2: (defrag) declare cursor for list of indexes to be defragged
DECLARE indexes CURSOR FOR
SELECT ObjectName, ObjectOwner = user_name(so.uid), ObjectId, IndexName, ScanDensity
FROM #fraglist f
JOIN sysobjects so ON f.ObjectId=so.id
WHERE ScanDensity <= @maxfrag
AND INDEXPROPERTY (ObjectId, IndexName, 'IndexDepth') > 0
-- Write to output start time for information purposes
SELECT 'Started defragmenting indexes at ' + CONVERT(VARCHAR,GETDATE())
-- Open the cursor
OPEN indexes
-- Loop through the indexes
FETCH NEXT
FROM indexes
INTO @tablename, @objectowner, @objectid, @indexname, @frag
WHILE @@FETCH_STATUS = 0
BEGIN
SET QUOTED_IDENTIFIER ON
SELECT @execstr = 'DBCC DBREINDEX (' + "'" +RTRIM(@objectowner) + '.' + RTRIM(@tablename) + "'" +
', ' + RTRIM(@indexname) + ') WITH NO_INFOMSGS'
SELECT 'Now executing: '
SELECT(@execstr)
EXEC (@execstr)
SET QUOTED_IDENTIFIER OFF
FETCH NEXT
FROM indexes
INTO @tablename, @objectowner, @objectid, @indexname, @frag
END
-- Close and deallocate the cursor
CLOSE indexes
DEALLOCATE indexes
-- Report on finish time for information purposes
SELECT 'Finished defragmenting indexes at ' + CONVERT(VARCHAR,GETDATE())
-- Delete the temporary table
DROP TABLE #fraglist
GO
---------------------------->SP END
 
from sql server 2005 onwards we can rebuild the reindex online...
 
------------------------------>SP BEGIN for update stats
CREATE PROCEDURE update_stats_Conditional
    @numberofrows int = 10000,
    @percentchange int = 15,
    @samplerate int = 10
AS
    SET NOCOUNT ON
    DECLARE @StatsUpdate TABLE
        (
          id int identity(1, 1),
          TableName sysname,
          IndexName sysname
        )
    DECLARE @max int,
        @tablename nvarchar(100),
        @indexname nvarchar(150),
        @sql nvarchar(4000)
    INSERT  INTO @StatsUpdate ( TableName, IndexName )
            SELECT  TableName = OBJECT_NAME(id),
                    IndexName = name
            FROM    sysindexes with ( nolock )
            WHERE   OBJECTPROPERTY(id, 'IsSystemTable') = 0
                    AND indid > 0
                    AND indid < 255
                    AND rowcnt > @numberofrows
                    AND CAST(rowmodctr as numeric(9, 0))
                    / CAST(rowcnt as numeric(9, 0)) * 100 > @percentchange
    select  @max = max(id)
    from    @StatsUpdate
    while @max <> 0
        begin
            select  @tablename = TableName,
                    @indexname = IndexName
            from    @StatsUpdate
            where   id = @max
            print 'Updating Statistics for ' + @tablename + ' ' + @indexname
            select  @sql = 'UPDATE STATISTICS ' + @tablename + ' '
                    + @indexname + char(13) + ' WITH SAMPLE '
                    + CONVERT(nvarchar(3), @samplerate) + ' PERCENT'
            EXEC sp_executesql @sql
            select  @max = @max - 1
        end
 
--------------------------------->SP END update stats
 
*sp_updatestats takes care of this on Sql server 2005 onwards.
 
This is very helpful to me might be helpful to someone as well.
 
Thanx.
Vinay
 
Reference: Internet.
 
 
 

Comments

No comments.

Leave a Comment

Please register or log in to leave a comment.