declare @test table (MixedData varchar(50))
insert into @test values ('44100-44110, 44150')


;WITH CTE (RangeData, SingleData) AS 
(SELECT SUBSTRING(MixedData, 1, Charindex(',', MixedData)-1),
        convert(int, SUBSTRING(MixedData, CharIndex(',', MixedData)+1, 50))
   FROM @test),
CTE2 (RangeStart, RangeEnd, SingleData) AS
(SELECT convert(int, SUBSTRING(RangeData, 1, CharIndex('-', RangeData)-1)),
        convert(int, SUBSTRING(RangeData, CharIndex('-', RangeData)+1, 50)),
        SingleData
   FROM CTE),
Tens (N)     AS (SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL
                 SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0), 
Thousands(N) AS (SELECT 1 FROM Tens t1 CROSS JOIN Tens t2 CROSS JOIN Tens t3), 
Millions (N) AS (SELECT 1 FROM Thousands t1 CROSS JOIN Thousands t2), 
Tally (N)    AS (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT 0)) FROM Millions)
SELECT N
  FROM Tally, CTE2
 WHERE N BETWEEN CTE2.RangeStart and CTE2.RangeEnd
    OR N = CTE2.SingleData

-- See how this starts off by creating a table 
-- and inserting representative test data into it?
-- If you do this, it makes it a LOT easier for all
-- of the volunteers on this site to just copy/paste
-- this into a query window and start working on it.
DECLARE @test TABLE (MixedData varchar(50))
INSERT INTO @test 
SELECT '44100-44110, 44150' UNION ALL
SELECT '44115,44125,44157' UNION ALL
SELECT ' 44250-44350, 44128, 44524-44555, 44112, 52144'

;WITH
-- This begins a virtual tally table. This query will be a LOT faster (< 1 second) with a permanent one.
-- See the article below for how to build one.
Tens (N)     AS (SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL
                 SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0), 
Thousands(N) AS (SELECT 1 FROM Tens t1 CROSS JOIN Tens t2 CROSS JOIN Tens t3), 
Millions (N) AS (SELECT 1 FROM Thousands t1 CROSS JOIN Thousands t2), 
Tally (N)    AS (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT 0)) FROM Millions),

-- first, need to break down each mixed data row into separate items, either a single item or a range.
-- See Jeff Moden's article The "Numbers" or "Tally" Table: What it is and how it replaces a loop.
-- at http://www.sqlservercentral.com/articles/T-SQL/62867/ for how a tally table can split strings apart.
Elements (Items) AS (
 SELECT RTRIM(LTRIM(SUBSTRING(',' + MixedData + ',',N+1,CHARINDEX(',',',' + MixedData + ',',N+1)-N-1)))
   FROM Tally, @test
  WHERE N < LEN(',' + MixedData + ',')
    AND SUBSTRING(',' + MixedData + ',',N,1) = ','),

-- Now, for each item, get the range start/end. A range will have a "-". 
-- If just a single item, use the item for both the range start and end.
Elements2 (RangeStart, RangeEnd) AS (
 SELECT CONVERT(INT, CASE WHEN CharIndex('-', Items) > 0 THEN LEFT(Items, CharIndex('-', Items)-1)
                          ELSE Items
                     END),
        CONVERT(INT, CASE WHEN CharIndex('-', Items) > 0 THEN SUBSTRING(Items, CharIndex('-', Items)+1, len(Items))
                          ELSE Items
                     END)
   FROM Elements)

-- Finally, return all the individual items
SELECT N
  FROM Tally, Elements2
 WHERE N BETWEEN Elements2.RangeStart and Elements2.RangeEnd

;WITH
Tens (N)     AS (SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL
                 SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0 UNION ALL SELECT 0), 
Thousands(N) AS (SELECT 1 FROM Tens t1 CROSS JOIN Tens t2 CROSS JOIN Tens t3), 
Millions (N) AS (SELECT 1 FROM Thousands t1 CROSS JOIN Thousands t2), 
Tally (N)    AS (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT 0)) FROM Millions)
SELECT N
  INTO dbo.TALLY
  FROM Tally
 ORDER BY N

ALTER TABLE dbo.TALLY ALTER COLUMN N int NOT NULL
ALTER TABLE dbo.TALLY ADD CONSTRAINT [PK_TALLY] PRIMARY KEY CLUSTERED (N) 

-- See how this starts off by creating a table 
-- and inserting representative test data into it?
-- If you do this, it makes it a LOT easier for all
-- of the volunteers on this site to just copy/paste
-- this into a query window and start working on it.
DECLARE @test TABLE (MixedData varchar(50))
INSERT INTO @test 
SELECT '44100-44110, 44150' UNION ALL
SELECT '44115,44125,44157' UNION ALL
SELECT ' 44250-44350, 44128, 44524-44555, 44112, 52144'

;WITH
-- first, need to break down each mixed data row into separate items, 
-- either a single item or a range. See Jeff Moden's article 
-- The "Numbers" or "Tally" Table: What it is and how it replaces a loop.
-- at http://www.sqlservercentral.com/articles/T-SQL/62867/ for how 
-- a tally table can split strings apart.
Elements (Items) AS (
 SELECT RTRIM(LTRIM(SUBSTRING(',' + MixedData + ',',N+1,CHARINDEX(',',',' + MixedData + ',',N+1)-N-1)))
   FROM dbo.Tally, @test
  WHERE N < LEN(',' + MixedData + ',')
    AND SUBSTRING(',' + MixedData + ',',N,1) = ','),

-- Now, for each item, get the range start/end. A range will have a "-". 
-- If just a single item, use the item for both the range start and end.
Elements2 (RangeStart, RangeEnd) AS (
 SELECT CONVERT(INT, CASE WHEN CharIndex('-', Items) > 0 THEN LEFT(Items, CharIndex('-', Items)-1)
                          ELSE Items
                     END),
        CONVERT(INT, CASE WHEN CharIndex('-', Items) > 0 THEN SUBSTRING(Items, CharIndex('-', Items)+1, len(Items))
                          ELSE Items
                     END)
   FROM Elements)

-- Finally, return all the individual items
SELECT N
  FROM dbo.Tally, Elements2
 WHERE N BETWEEN Elements2.RangeStart and Elements2.RangeEnd