Declare @DOB smallDatetime
       ,@Today smallDatetime
       ,@AgeYears int
       ,@AgePlusMonths int
       ,@AgePlusDays int	
       ,@LastBD datetime
       ,@LastMonthBD datetime

--======================--
set @DoB   = '20040228'
set @Today = '20080229'
--======================--

select 
 @AgeYears 
 = year(@today)-year(@dob)       
    - case  when month(@today) < month(@dob)               
              or (month(@today) = month(@dob) and day(@today) < day(@dob))               
            then 1              
            else 0        
      end
,@LastBD = dateadd(year,@AgeYears,@Dob)       
,@AgePlusMonths = datediff(month, @LastBD, @Today)  
    - case  when month(@today) <= month(@LastBD) and day(@today) < day(@LastBD)            
            then 1              
            else 0        
      end        
    - case  when month(@dob) = 2 and day(@dob) = 29
            then 1              
            else 0        
      end       
,@LastMonthBD = dateadd(month,@AgePlusMonths,@LastBD)
,@AgePlusDays = datediff(day, @LastMonthBD, @Today)

Select @today as today
      ,@DoB DoB
      ,@LastBD as LastBD
      ,@LastMonthBD as LastMonthBD
      ,@AgeYears AgeYears
      ,@AgePlusMonths As AgePlusMonths
      ,@AgePlusDays as AgePlusDays
		

create function dbo.ddfn_UT_AgeInYears
(
	@START_DATE		datetime,
	@END_DATE		datetime
)
returns		int
as
/*

Original code came from http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=74462
Original name F_AGE_IN_YEARS.

Updated 20080109 PH - comments updated.
Updated 20080423 PH - comments updated.

Function ddfn_UT_AgeInYears computes Age in years.

	Input parameters @START_DATE and @END_DATE
	are required.  If either or both parameters
	are null, the function returns null.
	if @START_DATE midnight is greater than
	@END_DATE midnight, the function returns NULL.

	i.e. SELECT dbo.ddfn_UT_AgeInYears('1988-02-29','2007-02-28')


	Age is defined as the number of anniversary dates
	reached or passed from @START_DATE through @END_DATE.

	Age is calculated based on midnight (00:00:00.000)
	of parameters @START_DATE and @END_DATE.
	Time of day is not used in the calculation.

  NULL is returned when the @END_DATE is earlier
  than the @START_DATE.

	For example, someone born 2000-02-15
	would be 5 years old on 2006-02-14, 
	but 6 years old on 2006-02-15.

	Someone born on Feb 29 would be a year
	older on Feb 28 in non-leap years, but
	would be a year older on Feb 29 in leap years.

	Function is valid for entire range of datetime
	values from 1753-01-01 00:00:00.000 to 
	9999-12-31 23:59:59.997.

	Quick test code:
	declare @strSql varchar(8000)
	set @strSql = ''
	SET @strSql = 'select ' 
	  + 'DOB AS BirthDate, '
	  + 'AsOfDt AS AsOfDate, '
    + 'database.dbo.ddfn_UT_AgeInYears(DOB,AsOfDt) AS UT_AgeInYears'
	  + ' FROM '
	  + ' (SELECT ''2004-02-29'' AS DOB, ''2004-02-28'' AS AsOfDt'
	  + ' union all SELECT ''2004-02-29'' AS DOB, ''2004-02-29'' AS AsOfDt'
	  + ' union all SELECT ''2004-02-29'' AS DOB, ''2004-03-01'' AS AsOfDt'
	  + ' union all SELECT '''' AS DOB, '''' AS AsOfDt'
	  + ' union all SELECT ''1988-02-29'' AS DOB, ''2007-02-27'' AS AsOfDt'
	  + ' union all SELECT ''1988-02-29'' AS DOB, ''2007-02-28'' AS AsOfDt'
	  + ' union all SELECT ''1988-02-29'' AS DOB, ''2007-03-01'' AS AsOfDt'
	  + ' union all SELECT '''' AS DOB, '''' AS AsOfDt'
	  + ' union all SELECT ''1988-02-29'' AS DOB, ''2008-02-28'' AS AsOfDt'
	  + ' union all SELECT ''1988-02-29'' AS DOB, ''2008-02-29'' AS AsOfDt'
	  + ' union all SELECT ''1988-02-29'' AS DOB, ''2008-03-01'' AS AsOfDt'
	  + ') HardCodeDateList'
	exec (@strSQL)


*/

begin

declare @AGE_IN_YEARS int

-- Start out by setting the times to midnight.
select	@START_DATE	= dateadd(dd,datediff(dd,0,@START_DATE),0),
	@END_DATE	= dateadd(dd,datediff(dd,0,@END_DATE),0)

if @START_DATE > @END_DATE
	begin
	return null
	end

select
	@AGE_IN_YEARS =
	datediff(yy,StartDateYearStart,EndDateYearStart) +
	-- Subtract 1 if anniversary date is after end date
	case
	when AnniversaryThisYear <= @END_DATE
	then 0
	else -1
	end
from
(
select	AnniversaryThisYear =
	dateadd(yy,datediff(yy,StartDateYearStart,EndDateYearStart),@START_DATE), 
	StartDateYearStart,
	EndDateYearStart
from
(
select	StartDateYearStart =
		dateadd(yy,datediff(yy,0,@START_DATE),0),
	EndDateYearStart  =
		dateadd(yy,datediff(yy,0,@END_DATE),0)
) aa
) a

return @AGE_IN_YEARS

end