SET NOCOUNT ON
DECLARE @BitBucket INT
DECLARE @Top INT
    SET @Top = 100000
--=============================================================================
-- Recursive CTE does the count
--=============================================================================
PRINT '========== Recursive CTE =========='
SET STATISTICS IO ON
SET STATISTICS TIME ON

  ;WITH cteTally
     AS (
		 SELECT 1 AS N
		  UNION ALL
		 SELECT N+1 FROM cteTally WHERE N < @Top
		)
 SELECT @BitBucket = N 
   FROM cteTally
 OPTION (MAXRECURSION 0)

SET STATISTICS TIME OFF
SET STATISTICS IO OFF
PRINT REPLICATE('=',100)

--=============================================================================
-- ROW_NUMBER CTE does the count
--=============================================================================
PRINT '========== ROW_NUMBER CTE =========='
SET STATISTICS IO ON
SET STATISTICS TIME ON

  ;WITH cteTally
     AS (
		 SELECT TOP(@Top) ROW_NUMBER() OVER(ORDER BY sc1.Type) AS N
		   FROM Master.dbo.spt_Values sc1,
				Master.dbo.spt_Values sc2
		)
 SELECT @BitBucket = N
   FROM cteTally 
  
SET STATISTICS TIME OFF
SET STATISTICS IO OFF
PRINT REPLICATE('=',100)