Create PROC [ODR].[SP_MainMenu]
	@currentuser VARCHAR(100)
   ,@side VARCHAR(5)
AS 
	WITH	LIST
			  AS ( SELECT DISTINCT
							Report_Group_Code
						   ,Report_Group_Name
				   FROM		odr.tbl_ExpandedPermissions
				   WHERE	ADLogon = @currentuser
				 )
		SELECT	DATA.Report_Group_Code
			   ,DATA.Report_Group_Name
			   ,ODRImage
		FROM	( SELECT	Report_Group_Code
						   ,Report_Group_Name
						   ,ROW_NUMBER() OVER ( ORDER BY Report_Group_Name ) AS rownum
				  FROM		list
				) DATA
				INNER JOIN 
				ODR.tbl_ReportGroups
				ON DATA.Report_Group_Code = ODR.tbl_ReportGroups.Report_Group_Code
		WHERE	CASE WHEN rownum <= ( SELECT	CAST(COUNT(*) AS NUMERIC(5, 2))
									  FROM		List
									) / 2 + 0.5 THEN 'left'
					 ELSE 'right'
				END = @side

GO

DECLARE @MaxNumber INT = 10;

IF OBJECT_ID(N'tempdb..#T') IS NOT NULL 
    DROP TABLE #T;
	
SELECT  Number
INTO    #T
FROM    dbo.Numbers
WHERE   Number BETWEEN 1 AND @MaxNumber;

WITH    Rt
          AS (SELECT TOP 50 PERCENT
                        Number
              FROM      #T
              ORDER BY  Number),
        Lt
          AS (SELECT    Number
              FROM      #T
              EXCEPT
              SELECT    Number
              FROM      Rt)
    SELECT  Number,
            'Right' AS Col
    FROM    Rt
    UNION ALL
    SELECT  Number,
            'Left' AS Col
    FROM    Lt
    ORDER BY Number;

WITH
baseCTE AS
(
 SELECT 
        (ROW_NUMBER() OVER (ORDER BY Name)-1)/5+1 AS RW, 
        (ROW_NUMBER() OVER (ORDER BY Name)-1)%5+1 AS CL,
        Name 
   FROM sys.tables
)
 SELECT MAX(CASE WHEN CL = 1 THEN Name ELSE '' END) AS Col1TableName,
        MAX(CASE WHEN CL = 2 THEN Name ELSE '' END) AS Col2TableName,
        MAX(CASE WHEN CL = 3 THEN Name ELSE '' END) AS Col3TableName,
        MAX(CASE WHEN CL = 4 THEN Name ELSE '' END) AS Col4TableName,
        MAX(CASE WHEN CL = 5 THEN Name ELSE '' END) AS Col5TableName
   FROM baseCTE
  GROUP BY RW
  ORDER BY RW