--===== Find Customers that bought both "A" AND "B"
 SELECT CustomerID
 FROM #Purchase
 WHERE ProductCode IN ('A')
INTERSECT
 SELECT CustomerID
 FROM #Purchase
 WHERE ProductCode IN ('B')
EXCEPT
--===== Find Customers that bought "C".
 SELECT CustomerID
   FROM #Purchase
  WHERE ProductCode IN ('C')
;

SELECT 
  CustomerId
FROM #Purchase
WHERE ProductCode IN ('A','B', 'C')
GROUP BY CustomerID
having sum(case when ProductCode = 'A' then 1 else 0 end) > 0
   and sum(case when ProductCode = 'B' then 1 else 0 end) > 0 
   and sum(case when ProductCode = 'C' then 1 else 0 end) = 0

CREATE INDEX IX_#Purchase_ProductCode
   ON #Purchase (
      ProductCode)
   INCLUDE (CustomerID)

SELECT a.CustomerID
   FROM #Purchase a
   LEFT OUTER JOIN #Purchase b
      ON    b.CustomerID   =  a.CustomerID
      AND   b.ProductCode  IN ('C')
   WHERE a.ProductCode IN ('A','B')
   AND    b.CustomerID   IS NULL
   GROUP BY a.CustomerID
   HAVING COUNT(DISTINCT a.ProductCode) = 2

Select	Distinct
	CustomerID
From	#Purchase
Where	ProductCode = 'A'
And	CustomerID In
(
	Select	CustomerID
	From	#Purchase
	Where	ProductCode = 'B'
)
And	CustomerID Not In
(
	Select	CustomerID
	From	#Purchase
	Where	ProductCode = 'C'
)

--===== Conditionally drop the test table to make
     -- reruns in SSMS easier.
     IF OBJECT_ID('tempdb..#Purchase','U') IS NOT NULL
        DROP TABLE #Purchase
;
--===== Create the test table
 CREATE TABLE #Purchase
        (
         PurchaseID     INT IDENTITY(1,1),
         CustomerID     INT,
         ProductCode    VARCHAR(1000)
         PRIMARY KEY CLUSTERED (PurchaseID)
        )
;

--===== Populate the test table with known data.
 INSERT INTO #Purchase
        (CustomerID, ProductCode)
------- Customer #1 precisely meets the criteria.
     -- Bought 'A' and 'B' but not 'C'.
 SELECT 1, 'A' UNION ALL
 SELECT 1, 'B' UNION ALL
------- Customer #2 also meets the criteria.
     -- Bought 'A' and 'B' and somthing else,
     -- but not 'C'.
 SELECT 2, 'A' UNION ALL
 SELECT 2, 'B' UNION ALL
 SELECT 2, 'D' UNION ALL
------- Customer #3 also meets the criteria.
     -- Bought 'A' and 'B' and something else,
     -- but not 'C'.
 SELECT 3, 'A' UNION ALL
 SELECT 3, 'B' UNION ALL
 SELECT 3, 'D' UNION ALL
 SELECT 3, 'A' UNION ALL
 SELECT 3, 'D' UNION ALL
------- Customer #4 doesn't meet the criteria.
     -- Bought 'A' and 'B' but also bought 'C'.
 SELECT 4, 'A' UNION ALL
 SELECT 4, 'B' UNION ALL
 SELECT 4, 'C' UNION ALL
------- Customer #5 doesn't meet the criteria.
     -- Bought 'A' and 'B' and something else,
     -- but also bought 'C'.
 SELECT 5, 'A' UNION ALL
 SELECT 5, 'B' UNION ALL
 SELECT 5, 'A' UNION ALL
 SELECT 5, 'B' UNION ALL
 SELECT 5, 'C' UNION ALL
 SELECT 5, 'D' UNION ALL
------- Customer #6 doesn't meet the criteria.
     -- Bought more than 1 of 'A' and something else
     -- but not 'B'.
 SELECT 6, 'A' UNION ALL
 SELECT 6, 'A' UNION ALL
 SELECT 6, 'D' UNION ALL
 SELECT 6, 'E' UNION ALL
------- Customer #7 doesn't meet the criteria.
     -- Bought more than 1 of 'B' and something else
     -- but not 'A'.
 SELECT 7, 'B' UNION ALL
 SELECT 7, 'B' UNION ALL
 SELECT 7, 'D' UNION ALL
 SELECT 7, 'E'

go

declare @i int = 10;
while @i < 100000
begin
	insert into #Purchase (CustomerID, ProductCode)
	select CustomerID + @i, ProductCode + Left(ProductCode, 1)
	From #Purchase
	set @i = @i * 2
end

SET STATISTICS IO ON

Create Index IX_ProductCode On #Purchase (ProductCode) Include (CustomerID);

 SELECT DISTINCT CustomerID
   FROM #Purchase P
  WHERE EXISTS (SELECT 1 FROM #Purchase P1
				WHERE P.customerid = P1.customerid 
				AND P1.productcode = 'A'
				)
  AND EXISTS (SELECT 1 FROM #Purchase P2
				WHERE P.customerid = P2.customerid 
				AND P2.productcode = 'B'
				)
  AND NOT EXISTS (SELECT 1 FROM #Purchase P3
				WHERE P.customerid = P3.customerid 
				AND P3.productcode = 'C'
				)